% Schulausgangsschrift (SAS) wesa
% Walter Entenmann
% 23.10.2011
% 30.11.2014: modifiziert, Duktus
%

% Grossbuchstaben
if not wortende:
  beginchar("A",46ut#,Ht#,0);
  else:
beginchar(oct"201",35ut#,Ht#,0);
    fi
pickup wesa_pen;
xpos:=0;
A_char;
zeigen;
endchar;

% Ligatur Ae
  beginchar(oct"013",50.376ut#,Ht#,0);
pickup wesa_pen;
xpos:=0;
latin_eA(xpos);
zeigen;
endchar;

if not wortende:
  beginchar("B",35.438ut#,Ht#,0);
  else:
beginchar(oct"202",26ut#,Ht#,0); 
    fi
  pickup wesa_pen;
xpos:=0;
 Horn(xpos);
     stamm((Ht),(0),xpos);
     Bauch(Bbreite',(Ht),ht+eta,D,xpos);
     mt:=0.5;
     Bauch(Bbreite,ht+eta,(0),D,xpos);
     xpos:=Sporn+Bbreite;
    tangente(D);
    Kern:=Bbreite-D;
zeigen;
endchar;

if not wortende:
  beginchar("C",29.192ut#,Ht#,0);
      else:
beginchar(oct"203",13.504ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
 C_form(xpos);
     Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("D",42.623ut#,Ht#,0);
      else:
beginchar(oct"204",33.009ut#,Ht#,0);
    fi
  pickup wesa_pen;
    xpos:=0;
 Horn(xpos);
     stamm((Ht),(0),xpos);
     mt:=0.3;
     Bauch(Dbreite,(Ht),(0),2D,xpos);
     xpos:=Sporn+Dbreite;
    tangente(11ut);
    Kern:=Dbreite-2D;
zeigen;
endchar;

if not wortende:
  beginchar("E",29.188ut#,Ht#,0);
      else:
beginchar(oct"205",12.5ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 Bauch(-10ut,(Ht),(ht),0,xpos+12.5ut);
     Bauch(-12.5ut,(ht),(0),0,xpos);
     schweif((Ht),(Ht-dd),D,0,-45,0.8,xpos);
     gerade((ht),(ht),dd,xpos-D);
     fahne((0),ht-Delta,D+((ht)-Delta)/m,0,angle(1,m),1.5,xpos-dd);
zeigen;
endchar;

if not wortende:
  beginchar("F",24ut#,Ht#,0);
      else:
beginchar(oct"206",20ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
stamm((Ht),(0),xpos+Sporn);
gerade((Ht),(Ht),Fdach,xpos-Sporn);
% schweif((ht-Delta),(ht-Delta-eta),15ut,-45,0,1.8,xpos-20ut);
     gerade((ht-Delta-eta),(ht-Delta-eta),Fdach',xpos-Fdach+Sporn-Sporn');
     fahne((ht-Delta-eta),ht-Delta,6.5ut,0,angle(1,m),1.5,xpos);
     if wortende:
       xpos:=Fdach;
     fi
     Kern:=Fdach-Sporn;
zeigen;
endchar;

% Ligatur Fe
beginchar(oct"014",26.876ut#,Ht#,0);
    pickup wesa_pen;
    xpos:=0;
    latin_eF(xpos);
zeigen;
endchar;

if not wortende:
  beginchar("G",36.688ut#,Ht#,dt#);
      else:
beginchar(oct"207",25ut#,Ht#,dt#);
    fi
  pickup wesa_pen;
xpos:=0;
bogen((Ht-dd),(Ht),ht,-Gbreite,0.4,150,-90,1,1,xpos+Gbreite);
bogen(ht,(0),5ht/6,Gbreite,0.4,-90,90,1,1.2,xpos);
stamm((ht),0,xpos);
if not wortende:
Uschl(xpos);
strich(xpos);
else:
  Uschl_e(xpos);
  fi
zeigen;
endchar;

if not wortende:
  beginchar("H",37ut#,Ht#,0);
      else:
beginchar(oct"210",26ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
stamm((Ht),(0),xpos+Sporn);
% schweif((ht-Delta),(ht-Delta-eta),Hbreite+Sporn,-45,0,1.8,xpos-Sporn);
    gerade((ht-Delta-eta),(ht-Delta-eta),Hbreite+Sporn,xpos-Sporn);
     stamm((Ht),(0),xpos);
      fahne((ht-Delta-eta),ht-Delta,11ut,0,angle(1,m),2.5,xpos);
zeigen;
endchar;

% Ligatur He
  beginchar(oct"015",37.876ut#,Ht#,0);
  pickup wesa_pen;
  xpos:=0;
  latin_eH(xpos);
zeigen;
endchar;

if not wortende:
  beginchar("I",30.454ut#,Ht#,0);
      else:
beginchar(oct"211",20ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
 gerade((Ht),(Ht),Hbreite,xpos);
     stamm((Ht),10ut,xpos);
     mt:=0.5;
     bogen(10ut,(0),(dd),-Hbreite,0.5,-90,135,1,1,xpos);
     xpos:=Hbreite;
    tangente(D);
    Kern:=Hbreite/2;
zeigen;
endchar;

if not wortende:
  beginchar("J",26.688ut#,Ht#,dt#);
      else:
beginchar(oct"212",15ut#,Ht#,dt#);
    fi
pickup wesa_pen;
  xpos:=0;
 gerade((Ht),(Ht),Jbreite,xpos);
     stamm((Ht),0,xpos);
if not wortende:
  Uschl(xpos);
  strich(xpos);
else:
  Uschl_e(xpos);
  fi
zeigen;
  endchar;

  if not wortende:
    beginchar("K",34.894ut#,Ht#,0);
        else:
beginchar(oct"213",19.206ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
stamm((Ht),(0),xpos);
     gerade((ht),(Ht),Hbreite,xpos+rt(0));
     schweif((ht),(0),Hbreite-2eta,angle(Hbreite-2eta,-ht),0,2,xpos-Hbreite+rt(0));
     Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("L",40.688ut#,Ht#,0);
      else:
beginchar(oct"214",25ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 schweif((Ht-D),(Ht),-D-dd,125,180,1,xpos+Lbreite);
     schweif((Ht),(0),-(Lbreite-D-dd),180,-150,1.5,xpos);
     schweif((0),(0),Lbreite,30,0,1,xpos);
     Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("M",65.688ut#,Ht#,0);
      else:
beginchar(oct"215",52ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 Flanke(sporn,Mbreite,xpos);
     stamm((Ht),(0),xpos);
     gerade((0),(Ht),Nbreite,xpos);
     stamm((Ht),(rho),xpos);
     stock(xpos);
zeigen;
endchar;

if not wortende:
  beginchar("N",54.188ut#,Ht#,0);
      else:
beginchar(oct"216",55ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
Flanke(sporn,Mbreite,xpos);
stamm((Ht),(0),xpos);
mN:=Ht/(Nbreite);
gerade((0),Ht-10ut,(Ht-10ut)/mN,xpos);
bogen(Ht-10ut,(Ht),(Ht-eta/2),10ut/mN+D,0.75,angle(1,mN),-30,1.8,1,xpos);
if not wortende:
  fahne((0),ht-Delta,2D+dd+((ht)-Delta)/m,10,angle(1,m),1,xpos-Nbreite-D);
fi
Kern:=Nbreite+D;
zeigen;
endchar;

if not wortende:
  beginchar("O",36.817ut#,Ht#,0);
      else:
beginchar(oct"217",27.009ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
    O_char;   % mit Kern
  zeigen;
endchar;

if not wortende:
  beginchar("P",27.688ut#,Ht#,0);
      else:
beginchar(oct"220",21ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
 Horn(xpos);
     stamm((Ht),(0),xpos);
     Bauch(Bbreite',(Ht),ht,D,xpos);
     fahne((0),ht-Delta,10ut+((ht)-Delta)/m,10,angle(1,m),1,xpos);
     if wortende:
       xpos:=Sporn+Bbreite';
     fi
     Kern:=Bbreite';
     zeigen;
endchar;

if not wortende:
  beginchar("Q",41.692ut#,Ht#,0);
      else:
beginchar(oct"221",26.004ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 aalt:=a;balt:=b;
     a:=A; b:=B;
     mt:=0.5;
     oval(xpos+delta);
     a:=aalt;b:=balt;
     schweif((s),(0),12.5ut,angle(1,-0.75),0,1.5,xpos-A);
     Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("R",39.291ut#,Ht#,0);
      else:
beginchar(oct"222",23.603ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
Horn(xpos);
     stamm((Ht),(0),xpos);
     Bauch(Bbreite',(Ht),ht,D,xpos);
     schweif(ht,(0),Bbreite'+2eta,angle(Bbreite',-ht),0,2,xpos+rt(0));
     Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("S",30.820ut#,Ht#,0);
      else:
beginchar(oct"223",20ut#,Ht#,0);
    fi
  pickup wesa_pen;
    xpos:=0;
 mt:=0.5;
     S_form(xpos); % mit Kern
    tangente(D);
zeigen;
endchar;

if not wortende:
  beginchar("T",33.833ut#,Ht#,0);
      else:
beginchar(oct"224",32ut#,Ht#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
 stamm((Ht),(0),xpos+Tbreite/2);
 gerade((Ht),(Ht),Tbreite,xpos-Tbreite/2);
 if not wortende:
   fahne((0),ht-Delta,2ut+dd+ht/m,10,angle(1,m),2,xpos-Tbreite/2);
 fi
 Kern:=Tbreite/2;
zeigen;
endchar;

if not wortende:
  beginchar("U",39.021ut#,Ht#,0);
      else:
beginchar(oct"225",25.333ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
U_char;
zeigen;
endchar;

if not wortende:
  beginchar("V",33.349ut#,Ht#,0);
      else:
beginchar(oct"226",28.611ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 V_kurzstrich(xpos);
      stamm((Ht),ht/2,xpos);
      mt:=0.1;
      bogen(ht,(0),ht+dt/2,Hbreite,0.25,-90,90,1.5,1.2,xpos);
      xtmp:=x0;ytmp:=y0;
      schweif(ht+dt/2,(Ht),-einroll,90,180,2,xpos);
    schweif((Ht),(Ht),s,angle(1,-mfahne),angle(1,2),1,xpos);
     if wortende:
      Kern:=xpos-D/m-0.25Hbreite;
      fi
      x0:=whatever; y0:=whatever;
      z0=(xtmp,ytmp);
    tangente(s+D);
zeigen;
endchar;

if not wortende:
  beginchar("W",53.349ut#,Ht#,0);
      else:
beginchar(oct"227",48.611ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 V_kurzstrich(xpos);
     stamm((Ht),ht/2,xpos);
     bogen(ht,(0),1.5ht,Hbreite,0.25,-90,90,1.5,1.2,xpos);
     stamm((Ht),ht,xpos);
      mt:=0.1;
      bogen(ht,(0),ht+dt/2,Hbreite,0.25,-90,90,1.5,1.2,xpos);
      xtmp:=x0;ytmp:=y0;
      schweif(ht+dt/2,(Ht),-einroll,90,180,2,xpos);
    schweif((Ht),(Ht),s,angle(1,-mfahne),angle(1,2),1,xpos);
           if wortende:
      Kern:=xpos-D/m-0.25Hbreite-Hbreite;
      fi
      x0:=whatever; y0:=whatever;
      z0=(xtmp,ytmp);
    tangente(s+D);
zeigen;
endchar;

if not wortende:
  beginchar("X",40.688ut#,Ht#,0);
      else:
beginchar(oct"230",25ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
gerade((0),(Ht),Hbreite+D,xpos);
schweif((Ht),(0),Hbreite,angle(Hbreite-eta,-Ht),0,3.5,xpos-Hbreite);
Fahne;
zeigen;
endchar;

if not wortende:
  beginchar("Y",35.021ut#,Ht#,dt#);
      else:
beginchar(oct"231",23.333ut#,Ht#,dt#);
    fi
  pickup wesa_pen;
 xpos:=0;
 V_kurzstrich(xpos);
     stamm((Ht),ht,xpos);
     bogen(ht,(0),1.5ht,Hbreite,0.25,-90,90,1.5,1.2,xpos);
     stamm((Ht),0,xpos);
     if not wortende:
       Uschl(xpos);
       strich(xpos);
     else:
       Uschl_e(xpos);
       fi
zeigen;
endchar;

if not wortende:
  beginchar("Z",40.688ut#,Ht#,0);
      else:
beginchar(oct"232",25ut#,Ht#,0);
    fi
  pickup wesa_pen;
xpos:=0;
 gerade((Ht),(Ht),Lbreite,xpos);
     gerade((Ht),(0),-Lbreite,xpos);
     schweif((0),(0),Lbreite,30,0,1,xpos);
     Fahne;
zeigen;
endchar;

% Umlaute
%\"A
if not wortende:
  beginchar(oct"304",46ut#,80ut#,0);
      else:
beginchar(oct"233",35ut#,42.5ut#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
  Umlaut(sporn+Abreite,xpos);
    A_char;
    zeigen;
endchar;
  
%\"O
if not wortende:
  beginchar(oct"326",36.817ut#,80ut#,0);
      else:
beginchar(oct"234",27.009ut#,42.5ut#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
    Umlaut(A,xpos);
    O_char;
    zeigen;
endchar;
 
%
%\"U
if not wortende:
  beginchar(oct"334",39.021ut#,42.5ut#,0);
      else:
beginchar(oct"235",25.333ut#,80ut#,0);
    fi
  pickup wesa_pen;
  xpos:=0;
 Umlaut(D/m+Hbreite/2,xpos);
    U_char;
    zeigen;
endchar;

%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%