%-------------------------------------------------------------
% This is ETH_GG.MF      as of Feb, 1997 by Olaf Kummer
% originally distributed by Abass B. Alamnehe [February, 1993]
%-------------------------------------------------------------

iff known eth_Ga:
cmchar "The letter Ga";
beginchar(eth_Ga,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(1u#,0);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
pos4(stem,10);
x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u;
bot y1=0; y2=.1h; y3=.75h; y4=.95h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e;
z5=z4l; lft_wing(5,.75u,.025h);

% BAR
penpos11(stem,0); x11=x4l; y11=y4+0.15h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_GU:
cmchar "The letter GU";
beginchar(eth_GU,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(1u#,3.5u#);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
pos4(stem,10);
x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u;
bot y1=0; y2=.1h; y3=.75h; y4=.95h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e;
z5=z4l; lft_wing(5,.75u,.025h);
x6=.5[x1r,x3r]; y6=.45h; rt_wing(6,1.5u,.025h);

% BAR
penpos11(stem,0); x11=x4l; y11=y4+0.15h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_GI:
cmchar "The letter GI";
beginchar(eth_GI,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(1u#,3.5u#);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
pos4(stem,10);
x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u;
bot y1=0; y2=.1h; y3=.75h; y4=.95h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e;
z5=z4l; lft_wing(5,.75u,.025h);
z6=z1r; rt_half_ellipse(6,1.5u);

% BAR
penpos11(stem,0); x11=x4l; y11=y4+0.15h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_GA:
cmchar "The letter GA";
beginchar(eth_GA,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(2.5u#,0);

pickup fine.nib; pos1(vair,0); penpos2(stem,0); penpos3(stem,0);
pos4(stem,5);
x1=w-7.5u; x2r=w-1.5u; x3r=w-.75u; x4l=w-4u;
bot y1=.15h; y2=.3h; y3=.73h; y4=.92h;
filldraw stroke z1e{right}...z2e..z3e{up}..{left}z4e;
z5=z4l; lft_wing(5,u,oo);
x6=x1; y6=y1+o;  lft_wing(6,0,o);

% BAR
penpos11(stem,0); x11=x4l-0.5u; y11=y4+0.18h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_GE:
cmchar "The letter GE";
beginchar(eth_GE,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(1u#,2.5u#);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
pos4(stem,10);

x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u;
bot y1=0; y2=.1h; y3=.75h; y4=.95h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e;
z5=z4l; lft_wing(5,.75u,.025h);
x6=x1; y6=y1; half_ring(6);

% BAR
penpos11(stem,0); x11=x4l; y11=y4+0.15h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_Ge:
cmchar "The letter Ge";
beginchar(eth_Ge,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(2u#,0);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
pos4(stem,10);   pos5(vair,105);
x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u; x5=x4l-1u;
bot y1=0; y2=.1h; y3=.7h; y4=.9h; y5=y4-.025h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e---z5e;
x6=x5-4.5u; y6=y5-.045h; gfive_ring(6,5,1/9);

% BAR
penpos11(stem,0); x11=x4l-1u; y11=y4+0.2h;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,11); endchar;


iff known eth_GO:
cmchar "The letter GO";
beginchar(eth_GO,8u#,.5[cap_height#,x_height#],paren_depth#);
adjust_fit(1u#,0);

pickup fine.nib; penpos1(stem,5); penpos2(stem,0); penpos3(stem,0);
penpos4(stem,0);
x1r=w-1.5u; x2r=x1r-.5u; x3r=w-.75u; x4l=w-4u;
bot y1=0; y2=.1h; y3=.7h; y4=.8h;
filldraw stroke z1e{left}...{up}z2e---z3e{up}..{left}z4e;

penpos6(stem,0); penpos7(stem,0); penpos8(stem,5);
x6=x7=x4l; x8=x6-.25u; y6=y4; y7=y6+.15h; y8=y6+.2h;
filldraw stroke z6e--z7e{up}...{left}z8e;
x5=x6l; y5=y6; lft_wing(5,.75u,.025h);

% BAR
penpos11(stem,0); x11=x8; y11=y8;
penpos11'(stem,0); x11'=x11; y11'+0.015h=y11;
lft_half_ellipse(11,2u); rt_half_ellipse(11',2u);
penlabels(1,2,3,4,5,7,8,11); endchar;