%% The Makor input conventions use a right single quote for two
%% purposes:
%%   * To enter a sheva vowel; and
%%
%%   * To enter an aleph.
%% Fortunately, context can most of the time tell the two apart.  We
%% adhere to these rules:
%%
%%   * At word beginnings, the ' always designates aleph.
%%   * Immediately following a consonant, it represents a sheva.
%%   * Immediately following a non-cantorial vowel, it represents an
%%   aleph.
%%
%% To force an ALEPH, precede the ' by a circumflex.
%%
%% To force a sheva, precede the ' by an underscore.
%%
%% The ligature breaker may also work to enforce proper typesetting.

%% We also handle here the special typesetting pertaining to the
%% holamdot-aleph pseudoligature.

input: 
	1;
output: 
	1;
aliases:
	CIRCUM	= 94
		;
	USCORE	= 95
		;
	QUOTE	= 39
		;
	AST	= 42
		;
%% Here we identify the characters which are valid parts of words.
	VALID	=  (96-122|128-135|144-148|150-173|176-181|192-199|140|189)
		;
	INVALID	= ^(96-122|128-135|144-148|150-173|176-181|192-199|140|189)
		;
	VOWEL	= (65-77|182-187)
		;
	HOLAMDOT	= 73
		;
	SPACE	= 32
		;
expressions:
	
	{HOLAMDOT}{QUOTE}	=> 171
		;
	{USCORE}{QUOTE}	=> 74
		;
	{CIRCUM}{QUOTE}	=> 96
		;
	{VOWEL}{QUOTE}	=> \1 96
		;
	{VALID}{QUOTE}	=> \1 74
		;
	{AST}{QUOTE}	=> \1 74 % % ast will get converted into dagesh-form
		;
	beg: {QUOTE}	=> 96
		;
	{SPACE}{QUOTE}	=> 32 96
		;
	{INVALID}{QUOTE}	=> \1 96
		;
	{QUOTE}		=> 96
		;